
A. Introduction
When you have more than two groups, a t-test (or the nonparametric equivalent) is no longer applicable. Instead, we use a technique called analysis of variance. This chapter covers analysis of variance designs with one or more independent variables, as well as more advanced topics such as interpreting significant interactions, and unbalanced designs. 

 B.  One-Way Analysis of Variance
The method used today for comparisons of three or more groups is called analysis of variance (ANOVA). This method has the advantage of testing whether there are any differences between the groups with a single probability associated with the test. The hypothesis tested is that all groups have the same mean. Before we present an example, notice that there are several assumptions that should be met before an analysis of variance is used.
Essentially, we must have independence between groups (unless a repeated measures design is used); the sampling distributions of sample means must be normally distributed; and the groups should come from populations with equal variances (called homogeneity of variance).

Example:

 

15 Subjects in three treatment groups X,Y and Z.

 

X         Y         Z

700      480      500

850      460      550

820      500      480

640      570      600

920      580      610

 

The null hypothesis is that the mean(X)=mean(Y)=mean(Z). The alternative hypothesis is that the means are not all equal. How do we know if the means obtained are different because of difference in the reading programs(X,Y,Z) or because of random sampling error? By chance, the five subjects we choose for group X might be faster readers than those chosen for groups Y and Z.
We might now ask the question, “What causes scores to vary from the grand mean?” In this example, there are two possible sources of variation, the first source is the training method (X,Y or Z).  The second source of variation is due to the fact that individuals are different.

SUM OF SQUARES total; 

SUM OF SQUARES between groups;

SUM OF SQUARES error （within groups）;

 

F ratio = MEAN SQUARE between groups/MEAN SQUARE error

             = (SS between groups/(k-1)) / (SS error/(N-k))
SAS codes:
DATA READING;
      INPUT GROUP $ WORDS @@;
DATALINES;
X 700 X 850 X 820 X 640 X 920
Y 480 Y 460 Y 500 Y 570 Y 580
Z 500 Z 550 Z 480 Z 600 Z 610
;
PROC ANOVA DATA=READING;
      TITLE ‘ANALYSIS OF READING DATA’;
      CLASS GROUP;
      MODEL WORDS=GROUP;
      MEANS GROUP;
RUN;
 
The ANOVA Procedure
Dependent Variable: words
 
Sum of
Source                      DF         Squares     Mean Square    F Value    Pr > F
Model                        2     215613.3333     107806.6667      16.78    0.0003
Error                       12      77080.0000       6423.3333
Corrected Total             14     292693.3333
 
                   
Now that we know the reading methods are different, we want to know what the differences are. Is X better than Y or Z? Are the means of groups Y and Z so close that we cannot consider them different? In general , methods used to find group differences after the null hypothesis has been rejected are called post hoc, or multiple comparison test.  These include Duncan’s multiple-range test, the Student-Newman-Keuls’ multiple-range test, least significant-difference test, Tukey’s studentized range test, Scheffe’s multiple-comparison procedure, and others.

To request a post hoc test, place the SAS option name for the test you want, following a slash (/) on the MEANS statement. The SAS names for the post hoc tests previously listed are DUNCAN, SNK, LSD, TUKEY, AND SCHEFFE, respectively.

For our example we have:

MEANS GROUP / DUNCAN;
Or MEANS GROUP / SCHEFFE ALPHA=.1
At the far left is a column labeled “Duncan Grouping.” Any groups that are not significantly different from one another will have the same letter in the Grouping column.

The ANOVA Procedure
                             Duncan's Multiple Range Test for words
 
  NOTE: This test controls the Type I comparison wise error rate, not the experiment wise error
                                             rate.
 
 
                               Alpha                        0.05
                               Error Degrees of Freedom       12
                               Error Mean Square        6423.333
 
 
                             Number of Means          2          3
                             Critical Range       110.4      115.6
 
 
                  Means with the same letter are not significantly different.
 
 
                  Duncan Grouping          Mean      N    group
 
                                A        786.00      5    x
 
                                B        548.00      5    z
                                B
                                B        518.00      5    y

 
C. Computing Contrasts
Suppose you want to make some specific comparisons. For example, if method X is a new method and methods Y and Z are more traditional methods, you may decide to compare method X to the mean of method Y and method Z to see if there is a difference between the new and traditional methods. You may also want to compare method Y to method Z to see if there is a difference. These comparisons are called contrasts, planned comparisons, or a priori comparisons. 

To specify comparisons using SAS software, you need to use PROC GLM (General Linear Model) instead of PROC ANOVA. PROC GLM is similar to PROC ANOVA and uses many of the same options and statements. However, PROC GLM is a more generalized program and can be used to compute contrasts or to analyze unbalanced designs.

PROC GLM DATA=READING;
      TITLE ‘ANALYSIS OF READING DATA -- PLANNED COMPARIONS’;
      CLASS GROUP;
      MODEL WORDS = GROUP;
      CONTRAST ‘X VS. Y AND Z’ GROUP -2 1 1;
      CONTRAST ‘METHOD Y VS Z’ GROUP 0 1 -1;
RUN;

 
The GLM Procedure
 
      Contrast                    DF     Contrast SS     Mean Square    F Value    Pr > F
 
      X VS. Y AND Z                1     213363.3333     213363.3333      33.22    <.0001
      METHOD Y VS Z                1       2250.0000       2250.0000       0.35    0.5649
 
 D.  Analysis of Variance: Two Independent Variables
Suppose we ran the same experiment for comparing reading methods, but using 15 male and 15 female subjects. In addition to comparing reading-instruction methods, we could compare male versus female reading speeds. Finally, we might want to see if the effects of the reading methods are the same for males and females. 
DATA TWOWAY;
      INPUT GROUP $ GENDER $ WORDS;
DATALINES;
X M 700 X M 850 X M 820 X M 640 X M 920
Y M 480 Y M 460 Y M 500 Y M 570 Y M 580

Z M 500 Z M 550 Z M 480 Z M 600 Z M 610

X F 900 X F 880 X F 899 X F 780 X F 899

Y F 590 Y F 540 Y F 560 Y F 570 Y F 555
Z F 520 Z F 660 Z F 525 Z F 610 Z F 645
;
PROC ANOVA DATA=TWOWAY;
      TITLE ‘ANALYSIS OF READING DATA’;
      CLASS GROUP GENDER;
      MODEL WORDS=GROUP | GENDER;
      MEANS GROUP | GENDER / DUNCAN;
RUN;
 
In this case, the term GROUP | GENDER can be written as 

            GROUP GENDER GROUP*GENDER

 
Source                      DF        Anova SS     Mean Square    F Value    Pr > F
group                        2     503215.2667     251607.6333      56.62    <.0001
gender                       1      25404.3000      25404.3000       5.72    0.0250
group*gender                 2       2816.6000       1408.3000       0.32    0.7314
 
In a two-way analysis of variance, when we look at GROUP effects, we are comparing GROUP levels without regard to GENDER. That is, when the groups are compared we combine the data from both GENDERS. Conversely, when we compare males to females, we combine data from the three treatment groups.

 The term GROUP*GENDER is called an interaction term. If group differences were not the same for males and females, we could have a significant interaction.

E. Interpreting Significant Interactions
Now consider an example that has a significant interaction term. We have two groups of children. One group is considered normal; the other, hyperactive.

data ritalin;
      do group = 'normal' , 'hyper';
      do drug = 'placebo','ritalin';
                  do subj = 1 to 4;
                        input activity @;
                        output;
                  end;
            end;
      end;
datalines;
50 45 55 52 67 60 58 65 70 72 68 75 51 57 48 55
;
proc anova data=ritalin;
      title 'activity study';
      class group drug;
      model activity=group | drug;
      means group | drug;
run;
 
Source                      DF        Anova SS     Mean Square    F Value    Pr > F
 
group                        1     121.0000000     121.0000000       8.00    0.0152
drug                         1      42.2500000      42.2500000       2.79    0.1205
group*drug                   1     930.2500000     930.2500000      61.50    <.0001
 
 
proc means data=ritalin nway noprint;
   class group drug;
   var activity;
   output out=means mean=;
run;
 
proc plot data=means;
  plot activity*drug=group;
run;
 
data ritalin_new;
set ritalin;
cond=group || drug;
run;
 
proc anova data=ritalin_new;
      title 'one-way anova ritalin study';
      class cond;
      model activity = cond;
      means cond / duncan;
run;
 
Duncan Grouping          Mean      N    cond
 
A        71.250      4    hyper placebo
B        62.500      4    normal ritalin
C        52.750      4    hyper ritalin
C
C        50.500      4    normal placebo
 
F.  N-Way Factorial Designs
With three independent variables, we have three main effects, three two-way interactions, and one three-way interaction. One usually hopes that the higher-order interactions are not significant since they complicate the interpretation of the main effects and the low-order interactions.

PROC ANOVA DATA=THREEWAY;
      TITLE ‘THREE WAY ANALYSIS OF VARIANCE’;
      CLASS GROUP GENDER DOSE;
      MODEL ACTIVITY = GROUP | GENDER | DOSE;
      MEANS GROUP | GENDER | DOSE;
RUN;
 
G. Unbalanced Designs: PROC GLM
Designs with an unequal number of subjects per cell are called unbalanced designs. For all designs that are unbalanced (except for one-way designs), we cannot use PROC ANOVA; PROC GLM (general linear model) is used instead. 

LMEANS will produce least-square, adjusted means for main effects. PDIFF option computes probabilities for pair wise difference.

Notice that there are two sets of values for SUM OF SQUARES, F VALUES, and probabilities; 

Notice new TITLE statements. TITLE2, TITLE3, TITLE4;

data pudding;
      input sweet flavor : $9. rating;
datalines;
1 vanilla 9
1 vanilla 7
1 vanilla 8
1 vanilla 7
2 vanilla 8
2 vanilla 7
2 vanilla 8
3 vanilla 6
3 vanilla 5
3 vanilla 7
1 chocolate 9
1 chocolate 9
1 chocolate 7
1 chocolate 7
1 chocolate 8
2 chocolate 8
2 chocolate 7
2 chocolate 6
2 chocolate 8
3 chocolate 4
3 chocolate 5
3 chocolate 6
3 chocolate 4
3 chocolate 4
;
proc glm data=pudding;
      title 'pudding taste evaluation';
      title3 'two-way ANOVA - unbalanced design';
      title5 '---------------------------------';
      class sweet flavor;
      model rating = sweet | flavor;
      means sweet | flavor;
      lsmeans sweet | flavor / pdiff;
run;
 
